@echo off
set DEST=C:\AkemiRetenciones
set APPNAME=Akemi Retenciones ISLR

echo.
echo  %APPNAME% - Instalador
echo  ============================================
echo.

if not exist "%DEST%" mkdir "%DEST%"
if not exist "%DEST%\XML" mkdir "%DEST%\XML"

echo  Copiando archivos...
xcopy /Y /E /I "%~dp0*.*" "%DEST%\" >nul
echo  Listo.
echo.

REM --- Detectar Escritorio ---
set DSKTP=
for /f "tokens=*" %%A in ('powershell -NoProfile -Command "[Environment]::GetFolderPath('Desktop')" 2^>nul') do set DSKTP=%%A
if defined DSKTP if exist "%DSKTP%" goto MKSHORTCUT

set DSKTP=%USERPROFILE%\Desktop
if exist "%DSKTP%" goto MKSHORTCUT

set DSKTP=%USERPROFILE%\OneDrive\Desktop
if exist "%DSKTP%" goto MKSHORTCUT

set DSKTP=%PUBLIC%\Desktop
if exist "%DSKTP%" goto MKSHORTCUT

echo  No se detecto el Escritorio.
echo  Ejecute directamente: %DEST%\AkemiRetenciones.exe
goto DONE

:MKSHORTCUT
echo  Creando acceso directo...
echo Set S=CreateObject("WScript.Shell") > "%TEMP%\mk.vbs"
echo Set L=S.CreateShortcut("%DSKTP%\%APPNAME%.lnk") >> "%TEMP%\mk.vbs"
echo L.TargetPath="%DEST%\AkemiRetenciones.exe" >> "%TEMP%\mk.vbs"
echo L.WorkingDirectory="%DEST%" >> "%TEMP%\mk.vbs"
echo L.Description="%APPNAME%" >> "%TEMP%\mk.vbs"
echo L.Save >> "%TEMP%\mk.vbs"
cscript //nologo "%TEMP%\mk.vbs"
del "%TEMP%\mk.vbs" >nul 2>&1

if exist "%DSKTP%\%APPNAME%.lnk" (
    echo  Acceso directo creado en el Escritorio.
) else (
    echo  No se creo el acceso directo.
    echo  Ejecute directamente: %DEST%\AkemiRetenciones.exe
)

:DONE
echo.
echo  ============================================
echo  INSTALACION COMPLETADA
echo  ============================================
echo  Directorio: %DEST%
echo.
echo  Presione una tecla para abrir la aplicacion...
pause >nul
start "" "%DEST%\AkemiRetenciones.exe"
